PortSystem			1.0

name            	arm-none-eabi-gcc
version         	4.3.3
set branch      	[join [lrange [split ${version} .] 0 1] .]
revision        	1

# Parameters for this port.
set newlibversion	1.18.0
set crossgcc-target arm-none-eabi
set default-languages --enable-languages="c"

description     	gcc cross-compilers for arm-none-eabi, with newlib runtime library.
long_description	gnu compiler for arm-none-eabi, with newlib runtime library.
homepage		http://gcc.gnu.org/
platforms       	darwin
categories      	cross devel
maintainers     	lilalinux.net:macports
master_sites		gnu:gcc/gcc-${version}/:gcc \
			ftp://sources.redhat.com/pub/newlib/:newlib \
			ftp://ftp.mirror.ac.uk/sites/sources.redhat.com/pub/newlib/:newlib \
			http://www.mirrorservice.org/sites/sourceware.org/pub/newlib/:newlib
distfiles		gcc-${version}.tar.bz2:gcc newlib-${newlibversion}.tar.gz:newlib
worksrcdir		gcc-${version}
checksums           gcc-4.3.3.tar.bz2 \
                    md5     cc3c5565fdb9ab87a05ddb106ba0bd1f \
                    sha1    e378b7a0cb0f7dbf6436f4efb5756e29a90fdc1c \
                    rmd160  8c20a52633df659cabd66925d8a105a7a1479820 \
                    newlib-1.18.0.tar.gz \
                    md5     3dae127d4aa659d72f8ea8c0ff2a7a20 \
                    sha1    a47d3b8a508304143334b36bdb5b33786a61ce94 \
                    rmd160  69d96fd323a23857072f30cb51899040099857cd

# All cross ports violate the mtree layout.
destroot.violate_mtree	yes

# Download everything to gcc/
dist_subdir			gcc

depends_lib		port:${crossgcc-target}-binutils \
			port:gmp \
			port:mpfr \
			port:gettext \
			port:libmpc

# gcc is .bz2, newlib is .gz.
# let's extract only gcc with MacPorts infrastructure, we'll do newlib manually.
use_bzip2		yes
extract.only		gcc-${version}.tar.bz2

# Extract newlib and create a symlink of newlib/newlib in gcc directory.
post-extract	{
	system "cd ${workpath} && gzip -dc ${distpath}/newlib-${newlibversion}.tar.gz | tar -xf -"
	system "ln -s ${workpath}/newlib-${newlibversion}/newlib ${workpath}/gcc-${version}/"
}

# Since we don't build gcc and binutils at the same time, gcc's Makefile will try to transform
# program names as gcc's name (add -${version} with ${version} being the version of gcc).
# But it won't work because binutils binaries don't have the ${version} suffix, and even if they
# had, they would actually have the binutils' version suffix (and not gcc's version).
# So let's tell gcc's Makefile not to do that mistake.

set environment [list AR_FOR_TARGET=${crossgcc-target}-ar \
				AS_FOR_TARGET=${crossgcc-target}-as \
				LD_FOR_TARGET=${crossgcc-target}-ld \
				NM_FOR_TARGET=${crossgcc-target}-nm \
				RANLIB_FOR_TARGET=${crossgcc-target}-ranlib]

#proc multilibpatch_enable { options dirnames exceptions matches } {
#	global worksrcpath
#	system "echo 'MULTILIB_OPTIONS += ${options}' >> ${worksrcpath}/gcc/config/arm/t-arm-none-eabi"
#	system "echo 'MULTILIB_DIRNAMES += ${dirnames}' >> ${worksrcpath}/gcc/config/arm/t-arm-none-eabi"
#	system "echo 'MULTILIB_EXCEPTIONS += ${exceptions}' >> ${worksrcpath}/gcc/config/arm/t-arm-none-eabi"
#	system "echo 'MULTILIB_MATCHES += ${matches}' >> ${worksrcpath}/gcc/config/arm/t-arm-none-eabi"
#}

# Build in a different directory, as advised in the README file.
pre-configure   {
	file mkdir "${workpath}/build"
}
configure.dir		${workpath}/build
configure.cmd		${workpath}/gcc-${version}/configure
configure.cc-append	-I${prefix}/include
configure.env		${environment}
configure.args		--target=${crossgcc-target} \
			--program-prefix=${crossgcc-target}- \
			--program-suffix=-${branch} \
			--infodir='${prefix}/share/info' \
			--mandir='${prefix}/share/man' \
			--with-gxx-include-dir=${prefix}/${crossgcc-target}/include/c++/${version}/ \
			--without-included-gettext \
			--disable-libgfortran \
			--enable-interwork \
			--enable-languages="c" \
			--disable-shared \
			--with-gnu-as \
			--with-gnu-ld \
			${default-languages}

#--without-headers 
#--with-libiconv-prefix=/opt/local 
#--with-gmp=/opt/local 
#--with-mpfr=/opt/local

configure.cc_archflags
configure.cxx_archflags
configure.objc_archflags
if {[info exists configure.ld_archflags]} {
    configure.ld_archflags
}
if {${os.platform} == "darwin" && ($build_arch == "x86_64" || $build_arch == "ppc64")} {
    configure.args-append --build=${build_arch}-apple-darwin${os.major}
}

build.dir		${workpath}/build

build.args		${environment}
destroot.args		${environment}

post-patch {
	namespace eval crossgcc {}

	# Fix the info pages and related stuff.
	#	
	# path: path to the doc directory (e.g. gas/doc/)
	# makefile: path to Makefile.in (e.g. gas/doc/Makefile.in)
	# name: name of the info page (e.g. as)
	# suffix: suffix of the souce page (texinfo or texi)
	proc crossgcc::fixinfo { path makefile name suffix } {
		global crossgcc-target worksrcpath

		# Fix the source
		reinplace "s|setfilename ${name}.info|setfilename ${crossgcc-target}-${name}.info|g" \
			${worksrcpath}/${path}/${name}.${suffix}
		reinplace "s|(${name})|(${crossgcc-target}-${name})|g" \
			${worksrcpath}/${path}/${name}.${suffix}
		reinplace "s|@file{${name}}|@file{${crossgcc-target}-${name}}|g" \
			${worksrcpath}/${path}/${name}.${suffix}
		
		# Fix the Makefile
		reinplace "s| ${name}.info| ${crossgcc-target}-${name}.info|g" \
			${worksrcpath}/${makefile}
		reinplace "s|/${name}.info|/${crossgcc-target}-${name}.info|g" \
			${worksrcpath}/${makefile}
		reinplace "s|^${name}.info|${crossgcc-target}-${name}.info|g" \
			${worksrcpath}/${makefile}
		reinplace "s| ${name}.pod| ${crossgcc-target}-${name}.pod|g" \
			${worksrcpath}/${makefile}
		reinplace "s|/${name}.pod|/${crossgcc-target}-${name}.pod|g" \
			${worksrcpath}/${makefile}
		reinplace "s|^${name}.pod|${crossgcc-target}-${name}.pod|g" \
			${worksrcpath}/${makefile}
		reinplace "s| ${name}.${suffix}| ${crossgcc-target}-${name}.${suffix}|g" \
			${worksrcpath}/${makefile}
		reinplace "s|/${name}.${suffix}|/${crossgcc-target}-${name}.${suffix}|g" \
			${worksrcpath}/${makefile}
		reinplace "s|^${name}.${suffix}|${crossgcc-target}-${name}.${suffix}|g" \
			${worksrcpath}/${makefile}
		
		# Rename the source
		file rename ${worksrcpath}/${path}/${name}.${suffix} \
			${worksrcpath}/${path}/${crossgcc-target}-${name}.${suffix}
		
		# Fix install-info's dir.
		# (note: this may be effectless if there was no info dir to be fixed)
		reinplace "s|--info-dir=\$(DESTDIR)\$(infodir)|--dir-file=\$(DESTDIR)\$(infodir)/${crossgcc-target}-gcc-dir|g" \
			"${worksrcpath}/${makefile}"
	}

	# Fix the gettext files and related stuff.
	#	
	# module: name of the module (e.g. gas)
	proc crossgcc::fixgettext { module } {
		global crossgcc-target worksrcpath

		if { [ file exists "${worksrcpath}/${module}/Makefile.in" ] } {
			reinplace "s|@PACKAGE@|${crossgcc-target}-@PACKAGE@|g" \
				"${worksrcpath}/${module}/Makefile.in"
			reinplace "s|${module}\.mo|${crossgcc-target}-${module}.mo|g" \
				"${worksrcpath}/${module}/Makefile.in"
		}
		if { [ file exists "${worksrcpath}/${module}/doc/Makefile.in" ] } {
			reinplace "s|@PACKAGE@|${crossgcc-target}-@PACKAGE@|g" \
				"${worksrcpath}/${module}/doc/Makefile.in"
		}
	}

	# gcc/doc/cpp.texi
	crossgcc::fixinfo gcc/doc/ gcc/Makefile.in cpp texi

	# gcc/doc/cppinternals.texi
	crossgcc::fixinfo gcc/doc/ gcc/Makefile.in cppinternals texi

	# gcc/doc/gcc.texi
	crossgcc::fixinfo gcc/doc/ gcc/Makefile.in gcc texi

	# gcc/doc/gccint.texi
	crossgcc::fixinfo gcc/doc/ gcc/Makefile.in gccint texi

	# gcc/fortran/gfortran.texi
	crossgcc::fixinfo gcc/fortran/ gcc/fortran/Make-lang.in gfortran texi

	# gcc/java/gcj.texi
	crossgcc::fixinfo gcc/java/ gcc/java/Make-lang.in gcj texi

	# gcc/doc/gccinstall.info
	crossgcc::fixinfo gcc/doc/ gcc/Makefile.in gccinstall info

	# gettext stuff.
	crossgcc::fixgettext gcc
	crossgcc::fixgettext libcpp
}

pre-destroot {
	# gcc needs the cross directory structure to be present
	# in order to fill it during installation.
	file mkdir "${destroot}/${prefix}/${crossgcc-target}/bin"
	file mkdir "${destroot}/${prefix}/${crossgcc-target}/lib"
}

post-destroot {
	namespace eval crossgcc {}

	# Rename a man page if it exists.
	#
	# section: section of the man page (e.g. 1)
	# manpage: name of the man page (e.g. cpp)
	proc crossgcc::rename_man_page { section manpage } {
		global crossgcc-target destroot prefix

		set manpage_path "${destroot}/${prefix}/share/man/man${section}/${manpage}.${section}"
		if { [ file exists ${manpage_path} ] } {
			file rename ${manpage_path} \
				"${destroot}/${prefix}/share/man/man${section}/${crossgcc-target}-${manpage}.${section}"
		}
	}

	# Stuff I don't want (either because they're in the system
	# or because they would conflict with other FSF ports)
	# (it's easier for maintainability purposes to fix things here)

	# aliases for locales (should be on the system)
	file delete "${destroot}/${prefix}/share/locale/locale.alias"
	
	# FSF propaganda (should already be there or would conflict)
	file delete -force "${destroot}/${prefix}/share/man/man7"

	# (host) libiberty
	file delete "${destroot}/${prefix}/lib/libiberty.a"

	# aliases for charsets (should already be there)
	file delete "${destroot}/${prefix}/lib/charset.alias"
	
	# Remove man pages for tools that are not built as part of cross-gcc
	file delete "${destroot}/${prefix}/share/man/man1/rmic.1"
	file delete "${destroot}/${prefix}/share/man/man1/rmiregistry.1"
	file delete "${destroot}/${prefix}/share/man/man1/jv-convert.1"
	file delete "${destroot}/${prefix}/share/man/man1/gij.1"
	
	# For some reason, some man pages are not prefixed while they should have been
	# (to avoid conflicting).
	crossgcc::rename_man_page 1 cpp
	crossgcc::rename_man_page 1 gcjh
	crossgcc::rename_man_page 1 gcov
	crossgcc::rename_man_page 1 jcf-dump
	crossgcc::rename_man_page 1 jv-scan
	
	# There is a bug in gcc/Makefile::install-driver
	# For cross compilers, $(GCC_INSTALL_NAME) is equal to
	# $(target_noncanonical)-gcc-$(version)
	# and hence the driver isn't installed.
	xinstall -c "${workpath}/build/gcc/xgcc" \
		"${destroot}/${prefix}/bin/${crossgcc-target}-gcc-${version}"
}

livecheck.type	regex
livecheck.url	http://gcc.gnu.org/releases.html
livecheck.regex	{<tr><td><a href="gcc-.*/">GCC (.*)</a></td>   <td>.*</td></tr>}








